Глава 20-2
Работа с бухгалтерскими итогами

• Работа с результатами запроса
  • Методы выборки результатов запроса
• ВыбратьСчета
• ПолучитьСчет
• ВыбратьКорСчета
• ПолучитьКорСчет
• ВыбратьВалюты
• ПолучитьВалюту
• ВыбратьПериоды
• ПолучитьПериод
• ВыбратьСубконто
• ПолучитьСубконто
• ВыбратьКорСубконто
• ПолучитьКорСубконто
• Атрибуты для обращения к результатам запроса
• Счет
• КорСчет
• Валюта
• НачДата
• КонДата
• Операция
• Методы обращения к результатам запроса
• Субконто
• КорСубконто
• ПредставлениеСубконто
• ПредставлениеКорСубконто
• ЭтоГруппа
• СНД, СНК, СКД, СКК, ДО, КО
• СНДРС, СНКРС, СКДРС, СККРС
• КорДО, КорКО
• ВыбранаПоДт, ВыбранаПоКт

Работа с результатами запроса

Атрибуты и методы, описанные в этом разделе, могут использоваться для обработки результатов работы метода ВыполнитьЗапрос.

Методы выборки результатов запроса

ВыбратьСчета

Открывает выборку счетов, для которых были получены итоги мето­дом ВыполнитьЗапрос.

Синтаксис:

ВыбратьСчета(<ФлагВсе>, <ФлагДК>, <Номер>, <РазвСальдо>)

Англоязычный синоним:

SelеctAccounts

Параметры:

Возвращаемое значение:

Число: 1 — если действие выполнено и в выборке есть хотя бы один счет;

0 — если действие не выполнено или в выборке нет ни одного счета.

Описание:

Метод ВыбратьСчета должен использоваться после получения итогов ме­тодом ВыполнитьЗапрос. Метод открывает выборку счетов, вошедших в за­прос.

Дополнительные условия на содержание выборки могут накладываться па­раметрами <ФлагВсе> и <ФлагДК>.

Параметр <РазвСальдо> может указываться только, если в запросе уста­новлено участие субконто. Позволяет указать, рассчитывать ли равернутое сальдо для субконто выборки. Результаты расчета могут быть получены при помощи функций СНДРС , СНКРС , СКДРС , СККРС.

Непосредственно извлечение счетов из выборки осуществляется при помо­щи метода ПолучитьСчет. Счета извлекаются в порядке возрастания кода счета.

Выборке, открываемой методом ВыбратьСчета, может быть присвоен но­мер — положительное целое число. Номер — это «метка» выборки. Номер мо­жет использоваться для обращения к результатам выборки при помощи метода ПолучитьСчет. Использование этой метки необходимо, если требуется полу­чить две группировки по счету.

Пример:

БухИтоги.Запрос(Дата1, Дата2);

БухИтоги.ВыбратьСчета();

Пока БухИтоги.ПолучитьСчет() = 1 Цикл

   Деб = БухИтоги.ДО();

   Кред = БухИтоги.КО();

КонецЦикла;

ПолучитьСчет

Получить из выборки следующий счет. Выборка должна быть пред­варительно открыта при помощи метода ВыбратьСчета.

Синтаксис:

ПолучитьСчет(<Номер>, <Счет>)

Англоязычный синоним:

GetAccount

Параметры:

Возвращаемое значение:

Число: 1 — следующий счет выбран успешно; 0 — следующий счет не вы­бран (отсутствует).

Описание:

Метод ПолучитьСчет выбирает очередной счет из выборки, содержащей счета из плана счетов. Перед применением метода ПолучитьСчет выборка должна быть открыта при помощи метода ВыбратьСчета. Счета извлекаются в порядке возрастания кода счета.

Метод ПолучитьСчет позволяет также обращаться к результатам выборки по номеру выборки, если предварительно было открыто несколько выборок. Номер выборки передается методу в качестве параметра <Номер>.

Следует иметь в виду, что, в отличие от аналогичного параметра метода ВыбратьСчета, параметр <Номер> метода ПолучитьСчет используется толь­ко для обращения к конкретной выборке.

Метод ПолучитьСчет позволяет также обращаться к конкретному значе­нию результа выборки. Значение счета выборки передается методу в качестве параметра <Счет>.

Если параметр <Счет> не задан, то метод ПолучитьСчет может использо­ваться для организации цикла по счетам. Условием цикла может служить ра­венство 1 возвращаемого значения метода: цикл выполняется, пока метод ПолучитьСчет возвращает 1.

Метод возвращает 0, когда очередной счет не выбран. Это происходит, если при предыдущем применении метода был выбран последний счет выборки.

Пример:

БухИтоги.Запрос(Дата1, Дата2);

БухИтоги.ВыбратьСчета();

Пока БухИтоги.ПолучитьСчет() = 1 цикл

   Деб = БухИтоги.ДО();

   Кред = БухИтоги.КО();

КонецЦикла;

ВыбратьКорСчета

Открывает выборку корреспондирующих счетов, для которых были получены итоги методом ВыполнитьЗапрос.

Синтаксис:

ВыбратьКорСчета(<ФлагВсе>, <ФлагДК>, <Номер>)

Англоязычный синоним:

SelectCorAccounts

Параметры:

Возвращаемое значение:

Число: 1 — если действие выполнено и в выборке есть хотя бы один счет;

0 — если действие не выполнено или в выборке нет ни одного счета.

Описание:

Метод ВыбратьКорСчета должен использоваться после получения итогов методом ВыполнитьЗапрос. Метод открывает выборку счетов, вошедших в запрос.

Дополнительные условия на содержание выборки могут накладываться па­раметрами <ФлагВсе> и <ФлагДК>.

Непосредственно извлечение счетов из выборки осуществляется при помо­щи метода ПолучитьКорСчет. Счета извлекаются в порядке возрастания кода счета.

Выборке, открываемой методом ВыбратьКорСчета, может быть присвоен номер — положительное целое число. Номер — это «метка» выборки. Номер может использоваться для обращения к результатам выборки при помощи ме­тода ПолучитьКорСчет. Использование этой метки необходимо, если требует­ся получить две группировки по счету.

Пример:

БухИтоги.Запрос(Дата1, Дата2);

БухИтоги.ВыбратьСчета();

Пока БухИтоги.ПолучитьСчет() = 1 Цикл

   БухИтоги.ВыбратьКорСчета();

   Пока БухИтоги.ПолучитьКорСчет() = 1 Цикл

      Деб = БухИтоги.ДО();

      Кред = БухИтоги.КО();

   КонецЦикла;

КонецЦикла;

ПолучитьКорСчет

Получить из выборки следующий корреспондирующий счет. Выбор­ка должна быть предварительно открыта при помощи метода

ВыбратьКорСчета.

Синтаксис:

ПолучитьКорСчет(<Номер>, <Счет>)

Англоязычный синоним:

GetCorAccount

Параметры:

Возвращаемое значение:

Число: 1 — следующий счет выбран успешно; 0 — следующий счет не вы­бран (отсутствует).

Описание:

Метод ПолучитьКорСчет выбирает очередной счет из выборки, содержа­щей счета из плана счетов. Перед применением метода ПолучитьКорСчет вы­борка должна быть открыта при помощи метода ВыбратьКорСчета. Счета извлекаются в порядке возрастания кода счета.

Метод ПолучитьКорСчет позволяет также обращаться к результатам вы­борки по номеру выборки. Номер выборки передается методу в качестве пара­метра <Номер>.

Следует иметь в виду, что, в отличие от аналогичного параметра метода ВыбратьКорСчета, параметр <Номер> метода ПолучитьКорСчет использует­ся только для обращения к конкретной выборке.

Метод ПолучитьСчет позволяет также обращаться к конкретному значе­нию результа выборки. Значение счета выборки передается методу в качестве параметра <Счет>.

Если параметр <Счет> не задан, то метод ПолучитьКорСчет используется для организации цикла по счетам. Условием цикла может служить равенство 1 возвращаемого значения метода: цикл выполняется, пока метод ПолучитьКорСчет возвращает 1.

Метод возвращает 0, когда очередной счет не выбран. Это происходит, если при предыдущем применении метода был выбран последний счет выборки.

Пример:

БухИтоги.Запрос(Дата1, Дата2);

БухИтоги.ВыбратьСчета();

Пока БухИтоги.ПолучитьСчет() = 1 цикл

   БухИтоги.ВыбратьКорСчета();

   Пока БухИтоги.ПолучитьКорСчет() = 1 цикл

      Деб = БухИтоги.КорДО();

      Кред=БухИтоги.КорКО();

   КонецЦикла;

КонецЦикла;

ВыбратьВалюты

Открывает выборку валют.

Синтаксис:

ВыбратьВалюты(<ФлагВсе>, <ФлагДК>, <Номер> , <РазвСальдо>, <Сортировка>)

Англоязычный синоним:

Select Currencies

Параметры:

Возвращаемое значение:

Число: 1 — если действие выполнено и в выборке есть хотя бы одна валюта;

0 — если действие не выполнено или в выборке нет ни одной валюты.

Описание:

Метод ВыбратьВалюты должен использоваться после выполнения метода ВыполнитьЗапрос. Метод открывает выборку валют.

Дополнительные условия на содержание выборки могут накладываться па­раметрами <ФлагВсе> и <ФлагДК>.

Параметр <РазвСальдо> может указываться только, если в запросе уста­новлено участие субконто. Позволяет указать, рассчитывать ли равернутое сальдо для субконто выборки. Результаты расчета могут быть получены при помощи функций СНДРС , СНКРС , СКДРС , СККРС.

Непосредственно извлечение валют из выборки осуществляется при помо­щи метода ПолучитьВалюту.

Выборке, открываемой методом ВыбратьВалюты, может быть присвоен но­мер — «метка» выборки. Номер может использоваться для обращения к резуль­татам выборки при помощи метода ПолучитьВалюту. Использование этой метки необходимо, если требуется получить две группировки по валюте.

Пример:

БухИтоги.Запрос(Дата1, Дата2);

БухИтоги.ВыбратьСчета();

Пока БухИтоги.ПолучитьСчет() = 1 цикл

   БухИтоги.ВыбратьВалюты();

   Пока БухИтоги.ПолучитьВалюту() = 1 цикл

      ДебВ=БухИтоги.ДО(2);

      КредВ=БухИтоги.КО(2);

   КонецЦикла;

КонецЦикла;

ПолучитьВалюту

Получить из выборки следующую валюту. Выборка должна быть предварительно открыта при помощи метода ВыбратьВалюты.

Синтаксис:

ПолучитьВалюту(<Номер>, <Валюта>}

Англоязычный синоним:

GetCurrency

Параметры:

Возвращаемое значение:

Число: 1 — следующая валюта выбрана успешно; 0 — следующий валюта не выбрана (отсутствует).

Описание:

Метод ПолучитьВалюту выбирает очередную валюту из выборки, откры­той при помощи метода ВыбратьВалюты.

Метод ПолучитьВалюту позволяет также обращаться к результатам кон­кретной выборки по ее номеру. Номер выборки передается методу в качестве параметра <Номер>.

Метод ПолучитьВалюту позволяет также обращаться к конкретному зна­чению результа выборки. Значение валюты выборки передается методу в каче­стве параметра <Валюта >.

Если параметр <Валюта> не задан, то метод ПолучитьВалюту использует­ся для организации цикла по валютам. Условием цикла может служить равен­ство 1 возвращаемого значения метода: цикл выполняется, пока метод ПолучитьВалюту возвращает 1.

Метод возвращает 0, когда очередная валюта не выбрана. Это происходит, если при предыдущем применении метода была выбрана последняя валюта выборки.

Пример:

БухИтоги.Запрос(Дата1, Дата2);

БухИтоги.ВыбратьСчета();

Пока БухИтоги.ПолучитьСчет() = 1 цикл

   БухИтоги.ВыбратьВалюты();

   Пока БухИтоги.ПолучитьВалюту() = 1 цикл

      ДебВ = БухИтоги.ДО(2);

      КредВ = БухИтоги.КО(2);

   КонецЦикла;

КонецЦикла;

ВыбратьПериоды

Открывает выборку периодов.

Синтаксис:

ВыбратьПериоды(<ФлагВсе>, <ФлагДК>, <Номер>, <РазвСальдо>)

Англоязычный синоним:

SelectPeriods

Параметры:

Возвращаемое значение:

Число: 1 — если действие выполнено и в выборке есть хотя бы один период;

0 — если действие не выполнено или в выборке нет ни одного периода.

Описание:

Метод ВыбратьПериоды должен использоваться после вызова метода ВыполнитьЗапрос. Метод открывает выборку, содержащую периоды итогов. Получение итогов в разрезе периодов доступно только если в запросе был задан параметр, устанавливающий разворачивание итогов с некоторой периодично­стью.

Дополнительные условия на содержание выборки могут накладываться па­раметрами <ФлагВсе> и <ФлагДК>.

Параметр <РазвСальдо> может указываться только, если в запросе уста­новлено участие субконто. Позволяет указать, рассчитывать ли равернутое сальдо для субконто выборки. Результаты расчета могут быть получены при помощи функций СНДРС , СНКРС , СКДРС , СККРС.

Непосредственно извлечение периодов из выборки осуществляется при по­мощи метода ПолучитьПериод.

Выборке, открываемой методом ВыбратьПериоды, может быть присвоен номер — «метка» выборки. Номер может использоваться для обращения к ре­зультатам выборки при помощи метода ПолучитьПериод. Использование этой метки необходимо, если требуется получить две группировки по периоду. Это позволяет получить две группировки но с одной периодичностью.

Пример:

БухИтоги.ВыполнитьЗапрос(Дата1, Дата2, , , , , "Месяц");

БухИтоги.ВыбратьСчета();

Пока БухИтоги.ПолучитьСчет() = 1 цикл

   БухИтоги.ВыбратьПериоды();

   Пока БухИтоги.ПолучитьПериод() = 1 цикл

      Деб = БухИтоги.ДО();

      Кред = БухИтоги.КО();

   КонецЦикла;

КонецЦикла;

ПолучитьПериод

Получить из выборки следующий период. Выборка должна быть предварительно открыта при помощи метода ВыбратьПериоды.

Синтаксис:

ПолучитьПериод(<Номер>, <ДатаНачалаПериода>}

Англоязычный синоним:

GetPeriod

Параметры:

Возвращаемое значение:

Число: 1 — следующий период выбран успешно; 0 — следующий период не выбран (отсутствует).

Описание:

Метод ПолучитьПериод выбирает очередной период из выборки, открытой при помощи метода ВыбратьПериоды.

Метод ПолучитьПериод позволяет также обращаться к результатам кон­кретной выборки по ее номеру. Номер выборки передается методу в качестве параметра <Номер>.

Метод ПолучитьПериод позволяет также обращаться к конкретному зна­чению результа выборки. Значение периода выборки передается методу в каче­стве параметра <ДатаНачалаПериода>.

Если параметр <ДатаНачалаПериода> не задан, то метод ПолучитьПериод используется для организации цикла по периодам. Условием цикла может служить равенство 1 возвращаемого значения метода: цикл вы­полняется, пока метод ПолучитьПериод возвращает 1.

Метод возвращает 0, когда очередной период не выбран. Это происходит, если при предыдущем применении метода был выбран последний период вы­борки.

Пример:

БухИтоги.ВыполнитьЗапрос(Дата1, Дата2, , , , , "Месяц");

БухИтоги.ВыбратьСчета();

Пока БухИтоги.ПолучитьСчет() = 1 цикл

   БухИтоги.ВыбратьПериоды();

   Пока БухИтоги.ПолучитьПериод() = 1 цикл

      Деб = БухИтоги.ДО();

      Кред = БухИтоги.КО();

   КонецЦикла;

КонецЦикла;

ВыбратьСубконто

Открывает выборку по субконто.

Синтаксис:

ВыбратьСубконто(<Индекс>, <ФлагВсе>, <ФлагДК>, <Номер>, <РазвСальдо>,

                     <Сортировка>, <РежимОбхода>)

Англоязычный синоним:

SelectSubconto

Параметры:

Возвращаемое значение:

Число: 1 — если действие выполнено и в выборке есть хотя бы одно субконто;

0 — если действие не выполнено или в выборке нет ни одного субконто.

Описание:

Метод ВыбратьСубконто должен использоваться после вызова метода ВыполнитьЗапрос. Метод открывает выборку по субконто.

Если обработка по субконто задавалась путем нескольких вызовов метода ИспользоватьСубконто, то параметр <Индекс> позволяет сослаться на суб­конто конкретного вида в порядке вызова метода ИспользоватьСубконто. Для этого параметром <Индекс> задается номер вызова метода ИспользоватьСубконто.

Дополнительные условия на содержание выборки могут накладываться па­раметрами <ФлагВсе> и <ФлагДК>.

Параметр <РазвСальдо> позволяет указать, рассчитывать ли равернутое сальдо для субконто выборки.

Извлечение субконто из выборки осуществляется при помощи метода ПолучитьСубконто.

Выборке, открываемой методом ВыбратьСубконто, может быть присвоен номер — «метка» выборки. Номер может использоваться для обращения к ре­зультатам выборки при помощи метода ПолучитьСубконто. Это позволяет получить две группировки по субконто данного вида.

Пример:

БухИтоги.ИспользоватьСубконто(ВидыСубконто.Материалы, , 1);

БухИтоги.ИспользоватьСубконто(ВидыСубконто.Склады, , 1);

БухИтоги.ВыполнитьЗапрос(ДатаНач, ДатаКон, "10");

БухИтоги.ВыбратьСубконто(1);

Пока БухИтоги.ПолучитьСубконто(1) = 1 цикл

   БухИтоги.ВыбратьСубконто(2);

   Пока БухИтоги.ПолучитьСубконто(2) = 1 цикл

      Деб = БухИтоги.ДО();

      Кред = БухИтоги.КО();

   КонецЦикла;

КонецЦикла;

ПолучитьСубконто

Получить из выборки следующее субконто. Выборка должна быть предварительно открыта при помощи метода ВыбратьСубконто.

Синтаксис:

ПолучитьСубконто(<Индекс>, <Номер>, <Субконто>)

Англоязычный синоним:

GetSubconto

Параметры:

Возвращаемое значение:

Число: 1 — следующее субконто выбрано успешно; 0 — следующе субконто не выбрано (отсутствует).

Описание:

Метод ПолучитьСубконто выбирает очередное субконто из выборки, от­крытой при помощи метода ВыбратьСубконто.

Метод ПолучитьСубконто позволяет также обращаться к результатам вы­борки по номеру выборки. Номер выборки передается методу в качестве пара­метра <Номер>.

Метод ПолучитьСубконто позволяет также обращаться к конкретному значению результа выборки. Значение субконто выборки передается методу в качестве параметра <Субконто>.

Если параметр <Субконто> не задан, то метод ПолучитьСубконто ис­пользуется для организации цикла по субконто. Условием цикла может слу­жить равенство 1 возвращаемого значения метода: цикл выполняется, пока ме­тод ПолучитьСубконто возвращает 1.

Метод возвращает 0, когда очередное субконто не выбрано. Это происходит, если при предыдущем применении метода было выбрано последнее субконто выборки.

Пример:

БухИтоги.ИспользоватьСубконто(ВидыСубконто.Материалы, , 1);

БухИтоги.ИспользоватьСубконто(ВидыСубконто.Склады, , 1);

БухИтоги.ВыполнитьЗапрос(ДатаНач, ДатаКон, "10");

БухИтоги.ВыбратьСубконто(1);

Пока БухИтоги.ПолучитьСубконто(1) = 1 цикл

   БухИтоги.ВыбратьСубконто(2);

   Пока БухИтоги.ПолучитьСубконто(2) = 1 цикл

      Деб = БухИтоги.ДО();

      Кред = БухИтоги.КО();

   КонецЦикла;

КонецЦикла;

ВыбратьКорСубконто

Открывает выборку по корреспондирующим субконто.

Синтаксис:

ВыбратьКорСубконто(<Индекс>, <ФлагВсе>, <ФлагДК>, <Номер>, <Сортировка>,

                   <РежимОбхода>)

Англоязычный синоним:

SelectCorSubconto

Параметры:

Возвращаемое значение:

Число: 1 — если действие выполнено и в выборке есть хотя бы одно субкон­то; 0 — если действие не выполнено или в выборке нет ни одного субконто.

Описание:

Метод ВыбратьКорСубконто должен использоваться после вызова метода ВыполнитьЗапрос. Метод открывает выборку по корреспондирующим суб­конто.

Если обработка по корреспондирующим субконто задавалась путем не­скольких вызовов метода ИспользоватьКорСубконто, то параметр <Индекс> позволяет сослаться на субконто конкретного вида в порядке вызова метода ИспользоватьКорСубконто. Для этого параметром <Индекс> задается номер вызова метода ИспользоватьКорСубконто.

Дополнительные условия на содержание выборки могут накладываться па­раметрами <ФлагВсе> и <ФлагДК>.

Извлечение субконто из выборки осуществляется при помощи метода ПолучитьКорСубконто.

Выборке, открываемой методом ВыбратьКорСубконто, может быть при­своен номер — «метка» выборки. Номер может использоваться для обращения к результатам выборки при помощи метода ПолучитьКорСубконто. Это по­зволяет получить две группировки по субконто данного вида.

Пример:

БухИтоги.ИспользоватьСубконто(ВидыСубконто.Товары, , 1);

БухИтоги.ИспользоватьКорСубконто(ВидыСубконто.Клиенты, , 1);

БухИтоги.ВыполнитьЗапрос(ДатаНач, ДатаКон);

БухИтоги.ВыбратьСубконто();

Пока БухИтоги.ПолучитьСубконто() = 1 цикл

   БухИтоги.ВыбратьКорСубконто();

   Пока БухИтоги.ПолучитьКорСубконто() =1 цикл

      Деб = БухИтоги.КорДО();

      Кред = БухИтоги.КорКО();

   КонецЦикла;

КонецЦикла;

ПолучитьКорСубконто

Получить из выборки следующее субконто. Выборка должна быть предварительно открыта при помощи метода ВыбратьКорСубконто.

Синтаксис:

ПолучитьКорСубконто(<Индекс>, <Номер>, <КорСубконто>)

Англоязычный синоним:

GetCorSubconto

Параметры:

Возвращаемое значение:

Число: 1 — следующее субконто выбрано успешно; 0 — следующе субконто не выбрано (отсутствует).

Описание:

Метод ПолучитьКорСубконто выбирает очередное корреспондирующее субконто из выборки, открытой при помощи метода ВыбратьКорСубконто.

Метод ПолучитьКорСубконто позволяет также обращаться к результатам выборки по номеру выборки. Номер выборки передается методу в качестве па­раметра <Номер>.

Метод ПолучитьКорСубконто позволяет также обращаться к конкретному значению результа выборки. Значение корсубконто выборки передается методу в качестве параметра <КорСубконто>.

Если параметр <КорСубконто> не задан, то метод ПолучитьКорСубконто используется для организации цикла по корреспогди-рующим субконто. Условием цикла может служить равенство 1 возвращаемого значения метода: цикл выполняется, пока метод ПолучитьКорСубконто воз­вращает 1.

Метод возвращает 0, когда очередное корреспондирующее субконто не вы­брано. Это происходит, если при предыдущем применении метода было выбра­но последнее субконто выборки.

Пример:

БухИтоги.ИспользоватьСубконто(ВидыСубконто.Товары, , 1);

БухИтоги.ИспользоватьКорСубконто(ВидыСубконто.Клиенты, , 1);

БухИтоги.ВыполнитьЗапрос(ДатаНач, ДатаКон);

БухИтоги.ВыбратьСубконто();

Пока БухИтоги.ПолучитьСубконто() = 1 цикл

   БухИтоги.ВыбратьКорСубконто();

   Пока БухИтоги.ПолучитьКорСубконто() = 1 цикл

      Деб = БухИтоги.КорДО();

      Кред = БухИтоги.КорКО();

   КонецЦикла;

КонецЦикла;

Атрибуты для обращения к результатам запроса

Счет

Текущий счет результатов запроса.

Синтаксис:

Счет

Англоязычный синоним:

Account

Описание:

Счет является атрибутом типа «Счет». При обращении к итогам запроса при помощи функций ВыбратьСчета, ПолучитьСчет, атрибут Счет равен текущему счету, выбранному функцией ПолучитьСчет.

Пример:

БухИтоги.Запрос(Дата1, Дата2);

БухИтоги.ВыбратьСчета();

Пока БухИтоги.ПолучитьСчет() = 1 цикл

   Сообщить(БухИтоги.Счет.Код + " ДО = " + БухИтоги.ДО());

КонецЦикла;

КорСчет

Корреспондирующий счет, для которого извлекаются результаты за­проса.

Синтаксис:

КорСчет

Англоязычный синоним:

CorAccount

Описание:

КорСчет является атрибутом типа «Счет». При обращении к итогам запро­са при помощи функций ВыбратьКорСчета, ПолучитьКорСчет, атрибут Счет равен текущему счету, выбранному функцией ПолучитьКорСчет.

Пример:

БухИтоги.Запрос(Дата1, Дата2);

БухИтоги.ВыбратьСчета();

Пока БухИтоги.ПолучитьСчет() = 1 цикл

   БухИтоги.ВыбратьКорСчета();

   Пока БухИтоги.ПолучитьКорСчет() = 1 цикл

      Сообщить(БухИтоги.КорСчет.Код + " ДО = " + БухИтоги.КорДО());

   КонецЦикла;

КонецЦикла;

Валюта

Валюта, по которой извлекаются результаты запроса.

Синтаксис:

Валюта

Англоязычный синоним:

Currency

Описание:

Атрибут Валюта имеет значение «Справочник.Валюты». Он позволяет по­лучить, текущую валюту при использовании методов ВыбратьВалюты и ПолучитьВалюту.

Пример:

БухИтоги.Запрос(Дата1, Дата2);

БухИтоги.ВыбратьСчета();

Пока БухИтоги.ПолучитьСчет() = 1 цикл

   БухИтоги.ВыбратьВалюты();

   Пока БухИтоги.ПолучитьВалюту() = 1 цикл

      Сообщить(БухИтоги.Счет.Код + "/" + БухИтоги.Валюта + " ДО == " +

               БухИтоги.ДО());

   КонецЦикла;

КонецЦикла;

НачДата

Начальная дата периода, за который извлекаются результаты запро­са.

Синтаксис:

НачДата

Англоязычный синоним:

BegDate

Описание:

Атрибут НачДата содержит начальную дату периода, за который извлека­ются итоги при использовании методов обхода периодов ВыбратьПериоды и ПолучитьПериод.

Пример:

БухИтоги.ВыполнитьЗапрос(Дата1, Дата2, , , , , "Месяц");

БухИтоги.ВыбратьСчета();

Пока БухИтоги.ПолучитьСчет() = 1 цикл

   БухИтоги.ВыбратьПериоды();

   Пока БухИтоги.ПолучитьПериод() = 1 цикл

      Сообщить("С " + БухИтоги.НачДата.Код + " по " + БухИтоги.КонДата +

               " ДО = " + БухИтоги.ДО());

   КонецЦикла;

КонецЦикла;

КонДата

Конечная дата периода, за который извлекаются результаты запроса.

Синтаксис:

КонДата

Англоязычный синоним:

EndDate

Описание:

Атрибут КонДата содержит конечную дату периода, за который извлекают­ся итоги при использовании методов обхода периодов ВыбратьПериоды и ПолучитьПериод.

Пример:

БухИтоги.ВыполнитьЗапрос(Дата1, Дата2, , , , , "Месяц");

БухИтоги.ВыбратьСчета();

Пока БухИтоги.ПолучитьСчет() = 1 цикл

   БухИтоги.ВыбратьПериоды();

   Пока БухИтоги.ПопучитьПериод() = 1 цикл

      Сообщить("С " + БухИтоги.НачДата.Код + " по " + БухИтоги.КонДата +

           " ДО = " + БухИтоги.ДО());

   КонецЦикла;

КонецЦикла;

Операция

Текущая операция, по которой выдаются итоги при использовании запроса.

Синтаксис:

Операция

Англоязычный синоним:

Operation

Описание:

Атрибут позволяет обращаться к текущей операции, если запрос получен с детализацией итогов по периоду «Операция» и «Проводка».

Пример:

БухИтоги.ВыполнитьЗапрос(Дата1, Дата2, , , , , "Проводки");

БухИтоги.ВыбратьСчета();

Пока БухИтоги.ПолучитьСчет() = 1 цикл

   БухИтоги.ВыбратьПериоды();

   Пока БухИтоги.ПолучитьПериод() = 1 цикл

      Сообщить("Операция " + БухИтоги.Операция.ПредставлениеПроводки());

   КонецЦикла;

КонецЦикла;

Методы обращения к результатам запроса

Субконто

Субконто, соответствующее текущему итогу.

Синтаксис:

Субконто(<Номер> | <ВидСубконто>)

Англоязычный синоним:

Subconto

Параметры:

Возвращаемое значение:

Значение субконто, соответствующее текущему итогу.

Описание:

Метод Субконто служит для получения значения субконто, соответствую­щего текущему итогу.

Метод применяется для получения текущего сукбонто при использовании методов ВыбратьСубконто и ПолучитьСубконто.

Пример:

БухИтоги.ИспользоватьСубконто(ВидыСубконто.Товары, , 1);

БухИтоги.ВыполнитьЗапрос(ДатаНач, ДатаКон);

БухИтоги.ВыбратьСубконто();

Пока БухИтоги.ПолучитьСубконто() = 1 цикл

   Сообщить(БухИтоги.Субконто());

КонецЦикла;

КорСубконто

Корреспондирующее субконто, соответствующее текущему итогу.

Синтаксис:

КорСубконто(<Номер>|<ВидСубконто>)

Англоязычный синоним:

CorSubconto

Параметры:

Возвращаемое значение:

Значение корреспондирующего субконто, соответствующее текущему итогу.

Описание:

Метод КорСубконто служит для получения значения корреспондирующего субконто, соответствующего текущему итогу. Метод применяется для получе­ния текущего сукбонто при использовании методов ВыбратьКорСубконто и ПолучитьКорСубконто.

Пример:

БухИтоги.ИспользоватьСубконто(ВидыСубконто.Товары, , 1);

БухИтоги.ИспользоватьКорСубконто(ВидыСубконто.Клиенты, , 1);

БухИтоги.ВыполнитьЗапрос(ДатаНач, ДатаКон);

БухИтоги.ВыбратьСубконто();

Пока БухИтоги.ПолучитьСубконто() = 1 цикл

   БухМтоги.ВыбратьКорСубконто();

   Пока БухИтоги.ПолучитьКорСубконто() = 1 цикл

      Сообщить(БухИтоги.Субконто() + "-" + БухИтоги.КорСубконто());

   КонецЦикла;

КонецЦикла;

ПредставлениеСубконто

Представление субконто, соответствующего текущему итогу.

Синтаксис:

ПредставлениеСубконто(<Номер>|<ВидСубконто>, <Краткое>]

Англоязычный синоним:

SubcontoPresentation

Параметры:

Возвращаемое значение:

Строковое представление для субконто, соответствующего текущему итогу.

Описание:

Представлением называется символьная строка, содержащая информацию из различных реквизитов объекта, являющегося значением субконто. Эта сим­вольная строка может быть использована для отображения значений субконто в различных отчетах.

Представление может быть задано только для видов субконто типа «Спра­вочник» или «Документ». Формат представления определяется в конфигурато­ре при редактировании свойств вида субконто.

Метод ПредставлениеСубконто позволяет получить представление для субконто, соответствующего текущему итогу.

Метод применяется для текущего сукбонто при использовании методов ВыбратьСубконто и ПолучитьСубконто.

Пример:

БухИтоги.ИспользоватьСубконто(ВидыСубконто.Товары, , 1);

БухИтоги.ВыполнитьЗапрос(ДатаНач, ДатаКон);

БухИтоги.ВыбратьСубконто();

Пока БухИтоги.ПолучитьСубконто() = 1 цикл

   Сообщить(БухИтоги.ПредставлениеСубконто());

КонецЦикла;

ПредставлениеКорСубконто

Представление корреспондирующего субконто, соответствующего те­кущему итогу.

Синтаксис:

ПредставлениеКорСубконто(<Номер>|<ВидСубконто>, <Краткое>)

Англоязычный синоним:

CorSubcontoPresentation

Параметры:

Возвращаемое значение:

Строковое представление для корреспондирующего субконто, соответст­вующего текущему итогу.

Описание:

Представлением называется символьная строка, содержащая информацию из различных реквизитов объекта, являющегося значением субконто. Эта символьная строка может быть использована для отображения значений субконто в различных отчетах.

Представление может быть задано только для видов субконто типа «Спра­вочник» или «Документ». Формат представления определяется в конфигурато­ре при редактировании свойств вида субконто.

Метод ПредставлениеКорСубконто позволяет получить представление для корреспондирующего субконто, соответствующего текущему итогу.

Метод применяется для текущего корреспондирующего сукбонто при ис­пользовании методов ВыбратьКорСубконто и ПолучитьКорСубконто.

Пример:

БухИтоги.ИспользоватьСубконто(ВидыСубконто.Товары, , 1);

БухИтоги.ИспользоватьКорСубконто(ВидыСубконто.Клиенты, , 1);

БухИтоги.ВыполнитьЗапрос(ДатаНач, ДатаКон);

БухИтоги.ВыбратьСубконто();

Пока БухИтоги.ПолучитьСубконто() = 1 цикл

   БухИтоги.ВыбратьКорСубконто();

   Пока БухИтоги.ПолучитьКорСубконто() = 1 цикл

      Сообщить(БухИтоги.ПредставлениеСубконто() + "-" +

                 БухИтоги.ПредставлениеКорСубконто());

   КонецЦикла;

КонецЦикла;

ЭтоГруппа

Определяет, является ли текущее значение группироки запроса по субконто группой или нет. Имеет смысл только для субконто типа «справочник».

Синтаксис:

ЭтоГруппа()

Англоязычный синоним:

IsGroup

Возвращаемое значение:

Число: 1 — значение группировки по субконто является группой; 0 — зна­чение группировки по субконто не является группой.

Описание:

Данный метод позволяет определить, является ли текущее значение груп­пироки запроса по субконто группой или нет. Метод можно применять незави­симо от типа данных вида субконто, однако он имеет смысл только для субкон­то типа «справочник», а для остальных выдает 0.

Пример:

Пока БухИтоги.ПолучитьСубконто() = 1 Цикл

   Если БухИтоги.ЭтоГруппа() = 1 Тогда

      Таб.ВывестиСекцию("Группа");

   Иначе

      Таб.ВывестиСекцию("Строка");

   КонецЕсли;

КонецЦикла;

СНД, СНК, СКД, СКК, ДО, КО

СНД — дебетовое сальдо на начало периода;

СКД — дебетовое сальдо на конец периода;

СНК — кредитовое сальдо на начало периода;

СКК — кредитовое сальдо на конец периода;

ДО — дебетовый оборот за период;

КО — кредитовый оборот за период.

Синтаксис:

СНД(<ТипСуммы>)

СНК(<ТипСуммы>)

СКД(<ТипСуммы>}

СКК(<ТипСуммы>)

ДО(<ТипСуммы>)

КО(<ТипСуммы>)

Англоязычные синонимы:

IDB

ICB

FDB

FCB

TD

ТС

Параметры:

Возвращаемое значение:

Число — сальдо или оборот.

Описание:

При работе с результатами запроса, соответствующие сальдо и обороты в соответствии с текущим уровнем вложенности группировок.

Пример:

БухИтоги.Запрос(Дата1, Дата2);

БухИтоги.ВыбратьСчета();

Пока БухИтоги.ПолучитьСчет() = 1 цикл

   ОстНачД = БухИтоги.СНД();

   ОстНачК = БухИтоги.СНК();

   ОборотД = БухИтоги.ДО();

   ОборотК = БухИтоги.КО();

   ОстКонД = БухИтоги.СКД();

   ОстКонК = БухИтоги.СКК();

КонецЦикла;

СНДРС, СНКРС, СКДРС, СККРС

СНДРС — дебетовое развернутое сальдо на начало периода;

СНКРС — кредитовое развернутое сальдо на начало периода;

СКДРС —дебетовое развернутое сальдо на конец периода;

СККРС —кредитовое развернутое сальдо на конец периода.

Синтаксис:

СНДРС(<ТипСуммы>)

СНКРС(<ТипСуммы>)

СКДРС(<ТипСуммы>}

СККРС(<ТипСуммы>)

Англоязычный синоним:

IDBRS

ICBRS

FDBRS

FCBRS

Параметры:

Возвращаемое значение:

Число — рассчитанное сальдо.

Описание:

При работе с итогами, полученными методом ВыполнитьЗапрос функции СНДРС, СНКРС, СКДРС, СККРС позволяют получить развернутое сальдо в контексте текущих группировок запроса.

Пример:

* В данном примере по каждой организации определяется развернутое саль­до по счетам, к которым относится вид субконто "Организации".

БухИтоги.ИспользоватьСубконто(ВидыСубконто.Организации, , 1);

БухИтоги.ВыполнитьЗапрос(ДатаНач, ДатаКон);

БухИтоги.ВыбратьСубконто(1);

Пока БухИтоги.ПолучитьСубконто(1) = 1 цикл

   ОстНачД = БухИтоги.СНДРС();

   ОстНачК = БухИтоги.СНКРС();

   ОстКонД = БухИтоги.СКДРС();

   ОстКонК = БухИтоги.СККРС();

КонецЦикла;

КорДО, КорКО

КорДО — дебетовый оборот между корреспонденциями;

КорКО — кредитовый оборот между корреспонденциями.

Синтаксис:

КорДО(<ТипСуммы>)

КорКО(<ТипСуммы>)

Англоязычные синонимы:

CorTD

СоrТС

Параметры:

Возвращаемое значение:

Число — вычисленный оборот.

Описание:

Функции доступны только при работе с итогам, полученными методом

ВыполнитьЗапрос.

Функции КорДО и КорКО предназначены для получения корреспондирую­щих оборотов между счетам или между субконто. Для их использования долж­ны быть организованы выборки методами ВыбратьСчета, ПолучитьСчет,

ВыбратьКорСчета, ПолучитьКорСчет или ВыбратьСубконто, ПолучитьСубконто, ВыбратьКорСубконто, ПолучитьКорСубконто.

Пример:

* В данном примере в переменной в переменных ОбДТ и ОбКТ образуются обороты с дебета основного счета в кредит корреспондирующего и наобо­рот соответственно.

БухИтоги.Запрос(Дата1, Дата2);

БухИтоги.ВыбратьСчета();

Пока БухИтоги.ПолучитьСчет() = 1 цикл

   БухИтоги.ВыбратьКорСчета();

   Пока БухИтоги.ПолучитьКорСчет() = 1 цикл

      ОбДТ = БухИтоги.КорДО();

      ОбКТ = БухИтоги.КорКО();

   КонецЦикла;

КонецЦикла;

ВыбранаПоДт, ВыбранаПоКт

ВыбранаПоДт — определение, выбран ли итог по дебету;

ВыбранаПоКт — определение, выбран ли итог по кредиту.

Синтаксис:

ВыбранаПоДт()

ВыбранаПоКт()

Англоязычный синоним:

SelectedByDt

SelectedByKt

Возвращаемое значение:

Число: 0 —данный итог по дебету(кредиту) не выбран; 1 —данный итог по дебету(кредиту) выбран.

Описание:

Данные функция используются при обходе результатов запроса с детализа­цией периода по операциям и проводкам. Они показывают для текущей опера­ции (проводки) попала ли она в запрос по дебетовой (кредитовой) корреспон­денции.

Пример:

БухИтоги.ВыполнитьЗапрос(Дата1, Дата2, "50", , , , "Проводки");

БухИтоги.ВыбратьСчета();

БухИтоги.ВыбратьПериоды();

КолПрих=0;

КолРасх=0;

Пока БухИтоги.ПолучитьПериод() = 1 Цикл

   Если БухИтоги.ВыбранаПоДт() = 1 Тогда

      КолПрих = КолПрих + 1;

   КонецЕсли;

   Если БухИтоги.ВыбранаПоКт() = 1 Тогда

      КолРасх = КолРасх + 1;

   КонецЕсли;

КонецЦикла;

---

---