Открывает выборку операций за период.
Синтаксис:
ВыбратьОперации(<НачалоПериода>, <КонецПериода>)
Англоязычный синоним:
SelectOpers
Параметры:
|
<НачалоПериода> |
Необязательный параметр. Выражение типа дата, документ или позиция документа, с которого устанавливается начало выборки операций. |
|
<КонецПериода> |
Необязательный параметр. Выражение типа дата, документ или позиция документа, на котором устанавливается конец выборки операций. |
Возвращаемое значение:
Число: 1 — действие выполнено и в выборке есть хотя бы одна операция;
0 — действие не выполнено или в выборке нет ни одной операции.
Описание:
Метод ВыбратьОперации открывает выборку, содержащую операции за указанный период.
Пример:
Опер = СоздатьОбъект("Операция");
Опер.ВыбратьОперации(ДатаНач, ДатаКон);
Пока Опер.ПолучитьОперацию() = 1 Цикл
Сообщить("Операция " + Опер.Содержание);
КонецЦикла;
Открывает выборку оперций с проводками за указанный период.
Синтаксис 1:
ВыбратьОперацииСПроводками(<НачалоПериода>, <КонецПериода>, <Фильтр>, <Валюта>,
<ПланСчетов>, <РазделительУчета>)
Синтаксис 2:
ВыбратьОперацииСПроводками(<НачалоПериода>, <КонецПериода>, <Счет>, <КорСчет>,
<Флаг>, <Валюта>, <ПланСчетов>, <РазделительУчета>)
Англоязычный синоним:
SelectOpersAndEntries
Параметры:
|
<НачалоПериода> |
Необязательный параметр. Выражение типа дата, документ или позиция документа, с которого устанавливается начало выборки операций. |
|
<КонецПериода> |
Необязательный параметр. Выражение типа дата, документ или позиция документа, на котором устанавливается конец выборки операций. |
|
<Фильтр> |
Необязательный параметр. Строка — условие отбора проводок. |
|
<ПланСчетов> |
Необязательный параметр. Значение типа «План Счетов». Если параметр не указан — по всем планам счетов. |
|
<РазделительУчета> |
Необязательный параметр. Значение разделителя учета. Если параметр не указан — по всем значениям разделителя учета. |
|
<Счет> |
Необязательный параметр. Счет — счет, по которому будут отбираться проводки. |
|
<КорСчет> |
Необязательный параметр. Счет — корреспондирующий счет, по которому будут отбираться проводки. Параметр имеет смысл, если указан параметр <Счет>. |
|
<Флаг> |
Необязательный параметр. Число — признак вида оборота. Параметр может принимать значения: 1 — отбирать проводки только по дебету счета; 2 — отбирать проводки только по кредиту счета; 3 — отбирать проводки и по дебету, и по кредиту. По умолчанию 3. |
|
<Валюта> |
Необязательный параметр. Значание типа «справочник» (вида справочника используемого для валютного учета) — признак отбора проводок по валюте. |
Возвращаемое значение:
Число: 1 — действие выполнено и в выборке есть хотя бы одна проводка;
0 — действие не выполнено или в выборке нет ни одной проводки.
Описание:
Метод ВыбратьОперацииСПроводками служит для выбора проводок операций за период. Параметрами могут являеться различные условия отбора проводок.
После вызова данного метода метод ПолучитьПроводку выбирает очередную проводку из выборки удовлетворяющую заданным условиям, а метод ПолучитьОперацию выбирает первую проводку слудующей операции удовлетворяющую заданным условиям.
Метод может вызываться с двумя вариантами набора параметров. В первом варианте основные условия отбора задаются специальной строкой-фильтром, во втором указанием счета и корреспондирующего счета.
В параметре <Фильтр> задаются критерии отбора проводок для включения в выборку. Если параметр не заполнен, в выборку включаются все проводки. В общем случае в параметре <Фильтр> могут находиться одна или несколько корреспонденции счетов или символьных строк, разделяемых точкой с запятой «;». Символьные строки представляют собой наборы символов, заключенные в кавычки (при передаче строки в явном виде в параметре внутри строки двойные кавычки задаются двумя символами двойных кавычек). Корреспонденции имеют вид:
n — проводки со счетом n;
n, m — проводки в дебет счета n с кредита счета m.
Здесь в качестве n и m может указываться звездочка («*»), она обозначает любой счет. Например, *, 51 — все проводки с кредита 51 счета.
В выборку включаются все проводки, удовлетворяющие следующим условиям:
Если в параметре <Фильтр> указаны корреспонденции счетов, то проводка должна соответствовать одной из этих корреспонденции.
Если параметре <Фильтр> указаны строки символов, то в проводке должна содержаться хотя бы одна из этих строк — либо в содержании операции, либо представлениях значений субконто и реквизитов проводки и операции.
Примеры:
|
50 |
— все проводки со счетом 50; |
|
50, * |
— все проводки в дебет 50 счета; |
|
* , 51 |
— все проводки с кредита 51 счета; |
|
50, 51 |
— все проводки в дебет 50 счета с кредита 51; |
|
51; 52 |
— все проводки со счетом 51 или счетом 52; |
|
46, 68.2 |
— все проводки в дебет 46 счета с кредита 68.2; |
|
"бумага" |
— все проводки, содержащие в содержании операции или в субконто или в реквизитах слово «бумага»; |
|
"бумага"; "картон" |
— все проводки, содержащие в содержании операции или в субконто или в реквизитах слово «бумага» или слово «картон»; |
|
*, 46; "бумага" |
— все проводки по кредиту 46 счета, содержащие в содержании операции или в субконто или в реквизитах слово «бумага»; |
Кроме того, в обоих вариантах задаются дополнительные условия: валюта, план счетов, разделитель учета.
Параметр <Валюта> является значением типа «Справочник» вида, определенного при настройке валютного учета в метаданных. Если параметр указан, в отбор будут включены проводки только по указанной валюте. При этом пустое значение типа «Справочник» соответствующего вида считается указанием отбора по пустой валюте. Для того, чтобы отбор по валюте не производился нужно либо опустить данный параметр, либо передать туда значение иного типа, например, пустую сроку.
Параметр <ПланСчетов> является значением типа «План Счетов». Если параметр указан, в отбор будут включены проводки только по указанному плану счетов.
Параметр <РазделительУчета> является значением объекта метаданных, выбранного в качестве разделителя учета.
Если указан параметр <РазделительУчета>, в отбор будут включены проводки с указанным значением разделителя учета.
Параметры <Счет> и <КорСчет> задают условние отбора проводок по счетам.
Если указан параметр <Счет>, будут отбраны проводки только по указанному счету. Дополнительным условие отбора является значением параметра <Флаг>.
Если указаны параметр <Счет> и <КорСчет>, будут отобораны проводки только по указанной креспонденции счетов.
Пример:
Опер = СоздатьОбъект("Операция");
Опер.ВыбратьОперацииСПроводками(ДатаНач, ДатаКон, "50, 51; ""По Чеку"" ");
Пока Опер.ПолучитьПроводку() = 1 Цикл
Сообщить("Сумма " + Опер.Сумма);
КонецЦикла;
Задает фильтр по субконто для функции ВыбратьОперацииСПроводками.
Синтаксис:
ИспользоватьСубконто(<ВидСубконто>, <Субконто>)
Англоязычный синоним:
UseSubconto
Параметры:
|
<ВидСубконто> |
Значение типа «ВидСубконто» — отбор проводок будет выполнен только для субконто указанного вида. |
|
<Субконто> |
Значение субконто — отбор проводок будет выполнен только для указанного субконто. Кроме того, в качестве значения данного параметра можно передавать «Список значений». |
Описание:
Метод ИспользоватьСубконто устанавливает фильтр по субконто, который используется при отборе проводок методом ВыбратьОперацииСПроводками.
Метод ИспользоватьСубконто может вызываться последовательно несколько раз. В этом случае фильтры, устанавливаемые этой функцией, суммируются.
Пример:
Опер = СоздатьОбъект("Операция");
Опер.ИспользоватьСубконто(ВидыСубконто.Организации, ВыбОрг);
Опер.ВыбратьОперацииСПроводками(ДатаНач, ДатаКон, "60");
Пока Опер.ПолучитьПроводку() = 1 Цикл
Сообщить("Сумма " + Опер.Сумма);
КонецЦикла;
Задает фильтр по корреспондирующим субконто для функции
ВыбратьОперацииСПроводками.
Синтаксис:
ИспользоватьКорСубконто(<ВидСубконто>, <Субконто>)
Англоязычный синоним:
UseCorSubconto
Параметры:
|
<ВидСубконто> |
Значение типа «ВидСубконто» — отбор проводок будет выполнен только для корреспондирующих субконто указанного вида. |
|
<Субконто> |
Значение субконто — отбор проводок будет выполнен только для указанного корреспондирующего субконто. Кроме того, в качестве значения данного параметра можно передавать «Список значений». |
Описание:
Метод ИспользоватьКорСубконто устанавливает фильтр по корреспондирующим субконто, который используется при отборе проводок методом ВыбратьОперацииСПроводками.
Метод ИспользоватьКорСубконто может вызываться последовательно несколько раз. В этом случае фильтры, устанавливаемые этой функцией, суммируются.
Пример:
Опер = СоздатьОбъект("Операция");
Опер.ИспользоватьСубконто(ВидыСубконто.Организации, ВыбОрг);
Опер.ИспользоватьКорСубконто(ВидыСубконто.Товары, ВыбТовар);
Опер.ВыбратьОперацииСПроводками(ДатаНач, ДатаКон, "60");
Пока Опер.ПолучитьПроводку() = 1 Цикл
Сообщить("Сумма " + Опер.Сумма);
КонецЦикла;
Открывает выборку операций или проводок, отобранных по значению отбора.
Синтаксис:
ВыбратьПоЗначению(<НачалоПериода>, <КонецПериода> , <ВидОтбора>, <3начение0тбора>)
Англоязычный синоним:
SelectByValue
Параметры:
|
<НачалоПериода> |
Необязательный параметр. Выражение типа дата, документ или позиция документа, с которого устанавливается начало выборки операций. |
|
<КонецПериода> |
Необязательный параметр. Выражение типа дата, документ или позиция документа, на котором устанавливается конец выборки операций. |
|
<ВидОтбора> |
Необязательный параметр. Символьная строка — название вида отбора (см. ниже). |
|
<3начение0тбора> |
Необязательный параметр. Значение отбора вида, указанного в параметре <ВидОтбора>. |
Возвращаемое значение:
Число: 1 — действие выполнено и в выборке есть хотя бы одна операция или проводка; 0 — действие не выполнено или в выборке нет ни одной операции или проводки.
Описание:
Метод ВыбратьПоЗначению открывает выборку, содержащую операции или проводки за указанный период.
Данный метод позволяет достаточно быстро отобрать операции или проводки по критерию отбора. Возможные критерии отборов настраиваются в конфигураторе и имеют свои идентификаторы (системные или идентификаторы объектов метаданных). Вид отбора определяет будет открыта выборка операций или проводок.
Параметр <ВидОтбора> должен содержать название вида отборав виде символьной строки.
Параметр <ВидОтбора> для отбора операций может принимать следующие значения (в скобках указан английский синоним):
|
"СуммаОперации" ("OperSum") |
Отбор по сумме операции. Доступно если в метаданных включен отбор по сумме операции. |
|
"Содержание" ("Description") |
Отбор по содержанию операции. Доступно если в метаданных включен отбор по содержанию операции. |
|
<РеквизитОперации> |
Отбор по дополнительному реквизиту операции. Идентификатор реквизита должен быть указан так, как это задано в метаданных. Доступно если в метаданных включен отбор по реквизиту операции. |
Параметр <ВидОтбора> для отбора проводок может принимать следующие значения (в скобках указан английский синоним):
|
"Счет" ("Account") |
Отбор по счету дебета или счету кредита проводки. Доступно если в метаданных включен отбор по счетам проводок. |
|
"СчетДт" ("AccountDt") |
Отбор по счету дебета проводки. Доступно если в метаданных включен отбор по дебету/кредиту счетов проводок. |
|
"СчетКт" ("AccountKt") |
Отбор по счету кредита проводки. Доступно если в метаданных включен отбор по дебету/кредиту счетов проводок. |
|
"Валюта" ("Currency") |
Отбор по валюте проводки. Доступно если в метаданных включен отбор по валюте проводок. |
|
<ВидСубконто> |
Отбор по виду субконто. Идентификатор вида субконто должен быть указан так, как он задан в метаданных. Доступно если в метаданных включен отбор по этому виду субконто. |
|
<РеквизитПроводки> |
Отбор по дополнительному реквизиту проводки. Идентификатор реквизита должен быть указан так, как он задан в метаданных. Доступно если в метаданных включен отбор по этому реквизиту проводки. |
Параметр <3начениеОтбора> задает значение отбора.
После выполнения данного метода обход операций (проводок) осуществляется методами ПолучитьОперацию и ПолучитьПроводку.
Пример:
Опер = СоздатьОбъект("Операция");
Опер.ВыбратьПоЗначению(ДатаНач, ДатаКон, "Счет", СчетПоКоду("60"));
Пока Опер.ПолучитьПроводку() = 1 Цикл
Сообщить("Сумма " + Опер.Сумма);
КонецЦикла;
Извлекает операции из выборки, открытой при помощи метода
ВыбратьОперции.
Синтаксис:
ПолучитьОперацию()
Англоязычный синоним:
GetOper
Возвращаемое значение:
Число: 1 — операция выбрана успешно; 0 — операция не выбрана (отсутствует).
Описание:
Метод ПолучитьОперацию выбирает очередную операцию из выборки, открытой при помощи метода ВыбратьОперации.
Метод ПолучитьОперацию используется для организации цикла по операциям. Условием цикла может служить равенство 1 возвращаемого значения метода: цикл выполняется, пока метод ПолучитьОперацию возвращает 1.
Метод возвращает 0, когда очередная операция не выбрана. Это происходит, если при предыдущем применении метода была выбрана последняя операция выборки.
Пример:
Опер = СоздатьОбъект("Операция");
Опер.ВыбратьОперации(ДатаНач, ДатаКон);
Пока Опер.ПолучитьОперацию() = 1 Цикл
Сообщить("Операция " + Опер.Содержание);
КонецЦикла;
Позиционирует объект по значению типа «Документ».
Синтаксис:
НайтиОперацию([<Документ>])
Англоязычный синоним:
FindOper
Параметры:
|
<Документ> |
Значение типа «Документ». |
Возвращаемое значение:
Число: 1 — действие выполнено, операция найдена; 0 — действие не выполнено, операция не найдена.
Описание:
Метод НайтиОперацию осуществляет поиск операции по значению типа «Документ».
В системе 1С:Предприятие каждая операция принадлежит документу. Причем операция принадлажит только одному документу, а у документа может существовать только одна операция. Операции введенные вручную принадлежат документам специального вида «Операция».
Поэтому не существует возможности передачи такого значения как «Операция». Для «идентификации» операции фактически используется значение документа, которому она принадлежит. Поэтому для позиционировании объекта «Операция» непосредственно на конкретную операцию используется значение типа «Документ».
Пример:
Опер = СоздатьОбъект("Операция");
Опер.НайтиОперацию(ВыбрДокумент);
Определяет выбрана ли в данный момент операция.
Синтаксис:
Выбрана()
Англоязычный синоним:
Selected
Возвращаемое значение:
Число: 1 — операция выбрана; 0 — операция не выбрана.
Описание:
При использовании объекта «Операция» созданного функцией СоздатьОбъект метод Выбрана определяет спозиционирован ли объект в настоящий момент на некоторой операции или нет.
При использовании данного метода к атрибуту документа Операция (который имеет тип «Операция») он определяет, существует ли реально операция у документа или нет.
При использовании в форме журнала операций (проводок) метод определяет спозиционирован ли курсор.
При использовании в форме операции метод определяет, записана новая операция или нет.
Пример:
Опер = СоздатьОбъект("Операция");
Опер.НайтиОперацию(ВыбрДокумент);
Если Опер.Выбрана() = 0 Тогда
Сообщить("Операция не найдена");
КонецЕсли;
Установить значение реквизита по имени идентификатора.
Синтаксис:
УстановитьАтрибут(<ИмяРеквизита>, <3начение>)
Англоязычный синоним:
SebAttrib
Параметры:
|
<ИмяРеквизита> |
Строковое выражение, содержащее имя реквизита, как оно задано в конфигураторе. |
|
<3начение> |
Выражение, содержащее устанавливаемое значение реквизита. |
Описание:
Метод УстановитьАтрибут позволяет установить значение реквизита по имени идентификатора, как оно задано в конфигураторе.
Пример:
Опер.УстановитьАтрибут("ЦенаРозн", ЦенаТов);
Получить значение реквизита по имени идентификатора.
Синтаксис:
ПолучитьАтрибут(<ИмяРеквизита>)
Англоязычный синоним:
GetAttrib
Параметры:
|
<ИмяРеквизита> |
Строковое выражение, содержащее имя реквизита, как оно задано в конфигураторе. |
Возвращаемое значение:
Значение реквизита <ИмяРеквизита>.
Описание:
Метод ПолучитьАтрибут позволяет получить значение реквизита по имени идентификатора, как оно задано в конфигураторе.
Пример:
ЦенаТов = Опер.ПолучитьАтрибут("ЦенаРозн");
Открывает выборку проводок текущей операции.
Синтаксис:
ВыбратьПроводки()
Англоязычный синоним:
Select Entries
Возвращаемое значение:
Число: 1 — действие выполнено и в выборке есть хотя бы одна проводка;
0 —действие не выполнено или в выборке нет ни одной проводки.
Описание:
Метод ВыбратьПроводки открывает выборку проводок текущей операции. Данный метод предназначен для организации перебора проводок операции и используется вмесет с методом ПолучитьПроводку.
Пример:
Опер = СоздатьОбъект("Операция");
Опер.НайтиОперацию(ВыбрДокумент);
Опер.ВыбратьПроводки();
Пока Опер.ПолучитьПроводку() = 1 Цикл
Сообщить("Проводка " + Опер.Дебет.Счет + " - " + Опер.Кредит.Счет);
КонецЦикла;
Получить проводку из выборки, открытой методом
ВыбратьПроводки.
Синтаксис:
ПолучитьПроводку()
Англоязычный синоним:
GetEntry
Возвращаемое значение:
Число: 1 — следующая проводка выбрана успешно; 0 — следующая проводка не выбрана (отсутствует).
Описание:
Метод ПолучитьПроводку выбирает очередную проводку из выборки, содержащей проводки текущей операции. Перед применением метода ПолучитьПроводку выборка должна быть открыта при помощи метода ВыбратьПроводки.
Метод ПолучитьПроводку используется для организации цикла по проводкам текущей операции. Условием цикла может служить равенство 1 возвращаемого значения метода: цикл выполняется, пока метод ПолучитьПроводку возвращает 1.
Метод возвращает 0, когда очередная проводка не выбрана. Это происходит, если при предыдущем применении метода была выбрана последняя проводка выборки.
Пример:
Опер = СоздатьОбъект("Операция");
Опер.НайтиОперацию(ВыбрДокумент);
Опер.ВыбратьПроводки();
Пока Опер.ПолучитьПроводку() = 1 Цикл
Сообщить("Проводка " + Опер.Дебет.Счет + " - " + Опер.Кредит.Счет);
КонецЦикла;
Определяет выбрана ли проводка операции.
Синтаксис:
ПроводкаВыбрана()
Англоязычный синоним:
EntrySelected
Возвращаемое значение:
Число: 1 — проводка выбрана; 0 — проводка не выбрана.
Описание:
Метод ПроводкаВыбрана позволяет определить, спозиционирована ли в настоящий момент некоторая проводка в операции или нет, то есть можно ли обращаться к атрибутам и методам проводки.
Пример:
Опер = СоздатьОбъект("Операция");
Опер.НайтиОперацию(ВыбрДокумент);
Опер.ВыбратьПроводки();
Опер.ПолучитьПроводку();
Если Опер.ПроводкаВыбрана() = 0 Тогда
Сообщить("Нет проводок в операции");
КонецЕсли;
Оперделяет количество проводок в операции включая и проводки и корреспонденции.
Синтаксис:
КоличествоПроводок()
Англоязычный синоним:
EntriesCount
Возвращаемое значение:
Целое число — количество проводок в текущей операции.
Описание:
Метод позволяет опеределить полное количество проводок и корреспонденции в операции.
Пример:
Опер = СоздатьОбъект("Операция");
Опер.НайтиОперацию(ВыбрДокумент);
Для Инд = 1 До Опер.КоличествоПроводок() Цикл
Опер.ПолучитьПроводкуПоНомеру(Инд);
КонецЦикла;
Выбрать в качестве текущей проводку по ее номеру и номеру корреспонденции.
Синтаксис 1:
ПолучитьПроводкуПоНомеру(<АбсолютныиНомерПроводки>)
Синтаксис 2:
ПолучитьПроводкуПоНомеру(<НомерПроводки>, <НомерКорреспонденции>)
Англоязычный синоним:
GetEntryByNumber
Параметры:
|
<АбсолютныйНомерПроводки> |
Необязатальный параметр. Число — абсолютный номер проводки в операции (включая проводки и корреспонденции). Если не задан –1. |
|
<НомерПроводки> |
Необязатальный параметр. Число — номер проводки в операции. |
|
<НомерКорреспонденции> |
Необязатальный параметр. Число — номер корреспонденции в проводке. Параметр имеет смысл, если указан параметр <НомерПроводки>. |
Возвращаемое значение:
Число: 0 — проводка не найдена; 1 — проводка найдена.
Описание:
Метод ПолучитьПроводкуПоНомеру выбирает в качестве текущей проводку или корреспонденцию проводки.
Если передан один параметр, то он воспринимается, как абсолютный номер проводки (корреспонденции) в операции среди всех проводок и корреспонденции. Если передано два параметра, то первый из них — это номер проводки, а второй — номер корреспонденции в проводке.
Пример:
Опер = СоздатьОбъект("Операция");
Опер.НайтиОперацию(ВыбрДокумент);
Опер.ПолучитьПроводкуПоНомеру(3, 2);
Для Инд = 1 До Опер.КоличествоПроводок() Цикл
Опер.ПолучитьПроводкуПоНомеру(Инд);
КонецЦикла;
Обращение к данным проводки по номеру.
Синтаксис:
Пров(<НомерПроводки>, <НомерКорреспонденции>)
Англоязычный синоним:
Entry
Параметры:
|
<НомерПроводки> |
Необязатальный параметр. Число — номер проводки в операции. Если параметр не задан, то используется текущая проводка. |
|
<НомерКорреспонденции> |
Необязатальный параметр. Число — номер корреспонденции в проводке. Параметр имеет смысл, если указан параметр <НомерКорреспонденции>. |
Возвращаемое значение:
Ссылка на указанную проводку.
Описание:
Метод Пров является специальным методом, позволяющим обратиться непосредственно к данным проводки операции по номеру, без установки текущей проводки. Возвращаемое методом значение является ссылкой на проводку. Оно не может использоваться как значение, а предназначено только для доступа к атрибутам проводки. В основном метод Пров имеет смысл применять в формулах типовых операций.
Метод Пров позволяет обратится к атрибутам проводки Сумма, СуммаВал, Количество, Валюта, Дебет, Кредит, <Реквизит>.
Пример:
Опер = СоздатьОбъект("Операция");
Опер.НайтиОперацию(ВыбрДокумент);
Сообщить(Пров(2, 3).Дебет.Счет);
Определяет номер текущей проводки.
Синтаксис:
НомерПроводки()
Англоязычный синоним:
EntryNumber
Возвращаемое значение:
Число — номер проводки.
Описание:
Для текущей проводки (корреспонденции) возвращает ее номер (не абсолютный, а именно номер проводки без учета корреспонденции).
Пример:
Опер = СоздатьОбъект ("Операция");
Опер.НайтиОперацию(ВыбрДокумент);
Для Инд = 1 До Опер.КоличествоПроводок() Цикл
Опер.ПолучитьПроводкуПоНомеру(Инд);
Сообщить("Проводка " + Опер.НомерПроводки() +
"Корр. " + Опер.НомерКорреспонденции());
КонецЦикла;
Выдает план счетов текущей проводки.
Синтаксис:
ПланСчетов()
Англоязычный синоним:
ChartOfAccounts
Возвращаемое значение:
Значение типа «План Счетов».
Описание:
Для текущей проводки возвращает ее план счетов.
Пример:
Опер = СоздатьОбъект("Операция");
Опер.НайтиОперацию(ВыбрДокумент);
Для Инд = 1 До Опер.КоличествоПроводок() Цикл
Опер.ПолучитьПроводкуПоНомеру(Инд);
Сообщить("Проводка " + Опер.НомерПроводки() + "Корр. " +
Опер.НомерКорреспонденции() + "Пл.сч." + Опер.ПланСчетов());
КонецЦикла;
Определяет номер текущей корреспонденции в операции.
Синтаксис:
НомерКорреспонденции()
Англоязычный синоним:
CorrespondenceNumber
Возвращаемое значение:
Число — номер текущей корреспонденции в проводке.
Описание:
Для текущей проводки (корреспонденции) возвращает ее номер корреспонденции, если проводка не сложная — 1.
Пример:
Опер = СоздатьОбъект("Операция");
Опер.НайтиОперацию(ВыбрДокумент);
Для Инд = 1 До Опер.КоличествоПроводок() Цикл
Опер.ПолучитьПроводкуПоНомеру(Инд);
Сообщить("Проводка " + Опер.НомерПроводки() +
"Корр. " + Опер.НомерКорреспонденции());
КонецЦикла;
Определяет является ли текущая проводка сложной.
Синтаксис:
СложнаяПроводка()
Англоязычный синоним:
ComplexEntry
Возвращаемое значение:
Число: 1 — текущая проводка является сложной; 0 — текущая проводка не является сложной.
Описание:
Для текущей проводки (корреспонденции) определяется является ли она сложной. Под сложной проводкой понимается проводка, состоящая из нескольких корреспонденции.
Пример:
Опер = СоздатьОбъект("Операция");
Опер.НайтиОперацию(ВыбрДокумент);
Для Инд = 1 До Опер.КоличествоПроводок() Цикл
Опер.ПолучитьПроводкуПоНомеру(Инд);
Если Опер.СложнаяПроводка() = 1 Тогда
Сообщить("Проводка сложная");
КонецЕсли;
КонецЦикла;
Выдает номер строки документа, по которой сформирована текущая проводка.
Синтаксис:
НомерСтрокиДокумента()
Англоязычный синоним:
DocLineNum
Возвращаемое значение:
Число — номер строки документа, сформировавшей данную проводку.
Описание:
При добавлении проводок в операцию в процессе проведения документа существует возможность привязать каждую проводку к определенной строке документа. Это позволяет в дальнейшем получить из документа по номеру строки дополнительную информацию о проводке. Для того, что в проводке был простален номер строки документа следует в модуле документа перед добавлением проводки в операцию использовать метод ПривязыватьСтроку.
Метод НомерСтрокиДокумента выдает для текущей проводки номер строки документа, который был привязан в момент добавления проводки.
Пример:
Опер = СоздатьОбъект("Операция");
Опер.НайтиОперацию(ВыбрДокумент);
Опер.ВыбратьПроводки();
Пока Опер.ПолучитьПроводку() = 1 Цикл
Сообщить("Номер строки " + Опер.НомерСтрокиДокумента());
КонецЦикла;
Получить представление для текущей проводки.
Синтаксис:
ПредставлениеПроводки(<ПоСубконто>)
Англоязычный синоним:
Entry Presentation
Параметры:
<ПоСубконто> Необязательный параметр. Флаг включения в представление проводки представления субконто проводки. Число:
0 — не включать представление субконто;
1 — включать представление субконто;
2 — включать развернутое представление субконто. Значение по умолчанию: 0.
Возвращаемое значение:
Строка — представление для текущей проводки.
Описание:
Представлением называется символьная строка, содержащая информацию из реквизитов проводки и операции. Эта строка может быть использована для отображения проводки в различных отчетах, диалогах и других визуальных элементах конфигурации. Формат представления определяется в конфигураторе при редактировании свойств проводки.
Метод ПредставлениеПроводки позволяет получить представление для текущей проводки.
Параметр метода позволяет указать, включать ли в представление проводки и представление субконто проводки. Представление субконо содержит информацию из реквизитов значения субконто. Представление может быть задано в конфигураторе при редактировании свойств вида субконто.
Пример:
Опер = СоздатьОбъект("Операция");
Опер.НайтиОперацию(ВыбрДокумент);
Опер.ВыбратьПроводки();
Пока Опер.ПолучитьПроводку() = 1 Цикл
Сообщить("Проводка " + Опер.ПредставлениеПроводки(1));
КонецЦикла;
Получить представление для субконто текущей проводки.
Синтаксис:
ПредставлениеСубконто()
Англоязычный синоним:
SubcontoPresentation
Возвращаемое значение:
Символьная строка — представление субконто текущей проводки.
Описание:
Представлением называется символьная строка, содержащая информацию из реквизитов субконто. Эта символьная строка может быть использована для отображения значений реквизитов субконто в различных отчетах, диалогах и других визуальных элементах конфигурации.
Представление может быть задано в конфигураторе при редактировании свойств вида субконто.
Метод ПредставлениеСубконто позволяет получить представление для всех субконто текущей проводки.
Пример:
Опер = СоздатьОбъект("Операция");
Опер.НайтиОперацию(ВыбрДокумент);
Опер.ВыбратьПроводки();
Пока Опер.ПолучитьПроводку() = 1 Цикл
Сообщить("Субконто " + Опер.ПредставлениеСубконто());
КонецЦикла;
Назначить тип для реквизита неопределенного вида.
Синтаксис:
НазначитьТип(<ИмяРеквизита>, <ИмяТипа>, <Длина>, <Точность>)
Англоязычный синоним:
SetType
Параметры:
|
<ИмяРеквизита> |
Строковое выражение — название реквизита операции или проводки неопределенного типа, как он назван в конфигураторе. |
|
<ИмяТипа> |
Строковое выражение — название типа данных (или Вид субконто), который назначается реквизиту операции или проводки. Например: "Строка", "Число", "Справочник.Товары", "Документ.РасходнаяНакладная" и т. п. |
|
<Длина> |
Необязательный параметр. Числовое выражение — длина поля представления данных. Имеет смысл только при задании числового или строкового типа. |
|
<Точность> |
Необязательный параметр. Числовое выражение — число знаков числа после десятичной точки. Имеет смысл только при задании числового типа. |
Описание:
Метод НазначитьТип позволяет назначить тип для реквизита, которому в конфигураторе назначен тип «Неопределенный».
Пример:
Операция.НазначитьТип("ТМЦ", "Справочник.Товары");
Создать новую операцию.
Синтаксис:
Новая()
Англоязычный синоним:
New
Описание:
Метод Новая используется для создания операций из встроенного языка, не принадлежащих документу какого либо вида.
Такая операция будет являться полным аналогом операции введенной вручную, то есть будет принадлежать документу специального вида «Операция». Операции, принадлежащие докуменам различных видов записываются при проведении документа без использования метода Новая.
Метод Новая может быть вызван только для объектов типа «Операция» созданных функцией СоздатьОбъект.
После вызова метода Новая могут быть заданы значения реквизитов операции и добавлены проводки. После этого для записи операции должен быть вызван метод Записать.
Пример:
* Создание и запись новой операции созданной в модуле отчета или обработки
Опер = СоздатьОбъект("Операция");
Опер.Новая();
Опер.Дата = РабочаяДата();
Опер.Содержание = "Выдача денег из кассы";
Опер.Записать();
Записать в информационную базу уже добавленные и заполненные проводки операции.
Синтаксис:
ЗаписатьПроводки()
Англоязычный синоним:
WriteEntries
Описание:
Метод ЗаписатьПроводки выполняет запись в информационную базу уже добавленных и заполненных проводок операции. Метод может использоваться только для атрибута «Операция» документа в момент проведения (в процедуре ОбработкаПроведения). При этом происходит обновление бухгалтерских итогов. Это позволяет при проведении документа обращаться к бухгалтерским итогам уже измененным проводками, записанными этим документом. После выполнения метода ЗаписатьПроводки и до окончания процедуры ОбработкаПроведение уже невозможно изменять или удалять проводки, добавленные до вызова этого метода.
Данный метод имеет смысл использовать, только в том случае, если существует необходимость обращения к итогам, измененным проводками записываемой операции.
Замечание. При записи сложной проводки, если у главной корреспонденции сложной проводки не указана сумма (равна 0), то она автоматически вычисляется на основании подчиненных корреспонденции.
Пример:
Процедура СписаниеСчетаНаСч20(Счт)
// создаем и формируем проводки
КонецПроцедуры
Процедура СписаниеСчета20На40()
// создаем и формируем проводки
КонецПроцедуры
Процедура ОбработкаПроведения()
Сч20 = СчетПоКоду("20");
Cч40 = CчeтПoKoдy("40");
СписаниеСчетаНаСч20(СчетПоКоду("25"));
СписаниеСчетаНаСч20(СчетПоКоду("26"));
Операция.ЗаписатьПроводки();
СписаниеСчета20На40();
Операция.Содержание = "Закрытие фин. результатов за " +
Формат(ДатаДок, "Д ММММГГГГ");
Операция.Записать();
КонецПроцедуры
Записать измененную или новую операцию.
Синтаксис:
Записать()
Англоязычный синоним:
Write
Описание:
Метод Записать выполняет запись новой или измененной операции.
Он может быть использован в следующих ситуациях:
· метод Записать может быть вызван для записи новой или измененной ручной операции (принадлежащей документу специального вида «Операция»). Такие операции могут создаваться и редактироваться пользователем вручную или из встроенного языка объектом «Операция», созданным функцией СоздатьОбъект.
· метод Записать может быть вызван для записи операции созданной при проведении документа в предопределенной процедуре ОбработкаПроведения. Данный метод должен быть вызван после заполнения операции содержанием реквизитов и проводками.
· этот метод может применяться в Модуле формы операции непосредственно к операции локального контекста, в этом случае данный метод отрабатывает те же действия, как интерактивное нажатие пользователем кнопки с формулой "#3аписать".
Замечание. При записи сложной проводки, если у главной корреспонденции сложной проводки не указана сумма (равна 0), то она автоматически вычисляется на основании подчиненных корреспонденции.
Пример:
* Создание и запись новой операции созданной в модуле отчета или обработки.
Опер = СоздатьОбъект("Операция");
Опер.Новая();
Опер.Дата = РабочаяДата();
Опер.Содержание = "Деньги по чеку";
Опер.НоваяПроводка();
Опер.Дебет.Счет = СчетПоКоду("50");
Опер.Кредит.Счет = СчетПоКоду("51");
Опер.Сумма = 1000000;
Опер.Записать();
* Запись операции в модуле документа в процессе проведения
Процедура ОбработкаПроведения()
Операция.Содержание = "Выдача денег из кассы";
Операция.НоваяПроводка();
Операция.Дебет.Счет = СчетПоКоду("71");
Операция.Дебет.Сотрудники = Сотрудник;
Операция.Кредит.Счет = СчетПоКоду("50");
Операция.Сумма = СуммаВыдачи;
Операция.Записать();
КонецПроцедуры
Удаление операции.
Синтаксис:
Удалить(<Режим>)
Англоязычный синоним:
Delete
Параметры:
|
<Режим> |
Необязательный параметр. Числовое выражение: |
1 — непосредственное удаление; 0 — пометка на удаление. Значение по умолчанию — 1.
Описание:
Метод Удалить удаляет (или помечает на удаление) текущую операцию.
Замечание. Непосредственное удаление объекта следует применять только в особых случаях, так как могут существовать ссылки на удаляемое значение в документах, справочниках и т. д. и непосредственное удаление может повлечет нарушение ссылочной целостности.
Данный метод может использоваться только для объектов, созданных функцией СоздатьОбъект.
Если метод Удалить применен к операции принадлежащей документу не специального вида «Операция», то происходит удаление (или пометка) всего документа.
Пример:
Опер = СоздатьОбъект("Операция");
Опер.НайтиОперацию(ВыбрДок);
Опер.Удалить(0);
Проверяет наличие пометки на удаление текущей операции.
Синтаксис:
ПометкаУдаления()
Англоязычный синоним:
DeleteMark
Возвращаемое значение:
Число: 1 — операция помечена на удаление; 0 — операция не помечена на удаление.
Описание:
Метод используется для проверки, помечена ли на удаление текущая операция или документ, которому принадлежит операция.
Пример:
Опер = СоздатьОбъект("Операция");
Опер.ВыбратьОперации(ДатаНач, ДатаКон);
Пока Опер.ПолучитьОперацию() = 1 Цикл
Если Опер.ПометкаУдаления() = 1 Тогда
Сообщить(Опер.Документ);
КонецЕсли;
КонецЦикла;
Снять пометку удаления операции.
Синтаксис:
СнятьПометкуУдаления()
Англоязычный синоним:
ClearDeleteMark
Описание:
Метод СнятьПометкуУдаления снимает пометку удаления текущей операции.
Данный метод может использоваться только для объектов, созданных функцией СоздатьОбъект. Если метод СнятьПометкуУдаления применен к операции принадлежащей документу не специального вида «Операция», то происходит снятие пометки удаления всего документа.
Пример:
Опер = СоздатьОбъект("Операция");
Опер.ВыбратьОперации(ДатаНач, ДатаКон);
Пока Опер.ПолучитьОперацию() = 1 Цикл
Если Опер.ПометкаУдаления() = 1 Тогда
Опер.СнятьПометкуУдаления();
КонецЕсли;
КонецЦикла;
Возвращает время текущей операции.
Синтаксис:
ПолучитьВремя(<Часы>, <Минуты>, <Секунды>)
Англоязычный синоним:
GetTime
Параметры:
|
<Часы> |
Необязательный параметр. Идентификатор переменной, в которую метод возвращает число — час времени операции. |
|
<Минуты> |
Необязательный параметр. Идентификатор переменной, в которую метод возвращает число — минуты времени операции. |
|
<Секунды> |
Необязательный параметр. Идентификатор переменной, в которую метод возвращает число — секунды времени операции. |
Возвращаемое значение:
Строковое значение времени в виде "ЧЧ.ММ.СС".
Описание:
Метод ПолучитьВремя возвращает время операции. Время записывается в переменные, передаваемые как параметры при вызове метода.
Пример:
Перем Час;
Перем Минута;
Перем Секунда;
Опер = СоздатьОбъект("Операция");
Опер.ВыбратьОперации(ДатаНач, ДатаКон);
Пока Опер.ПолучитьОперацию() = 1 Цикл
Опер.ПолучитьВремя(Час, Минута, Секунда);
КонецЦикла;
Задает время текущей операции.
Синтаксис:
УстановитьВремя(<Часы>, <Минуты>, <Секунды>)
Англоязычный синоним:
SetTime
Пареметры:
|
<Часы> |
Необязательный параметр. Число — час операции. |
|
<Минуты> |
Необязательный параметр. Число — минуты операции. |
|
<Секунды> |
Необязательный параметр. Число — секунды операции. |
Описание:
Метод УстановитьВремя изменяет время операции.
Данный метод может использоваться только для объектов, созданных функцией СоздатьОбъект. Так как время является значением относящимся к документу, то вызов этого метода изменяет время собственно документа, которому принадлежит операция.
Пример:
Перем Час;
Перем Минута;
Перем Секунда;
Опер = СоздатьОбъект("Операция");
Опер.ВыбратьОперации(ДатаНач, ДатаКон);
Пока Опер.ПолучитьОперацию() = 1 Цикл
Опер.ПолучитьВремя(Час, Минута, Секунда);
Опер.УстановитьВремя(Час + 1, Минута, Секунда);
КонецЦикла;
Возвращает значение типа «Документ» содержащий документ, которому принадлежит операция.
Синтаксис:
ПолучитьДокумент()
Англоязычный синоним:
GetDocument
Возвращаемое значение:
Значение типа «Документ».
Описание:
Метод ПолучитьДокумент возвращает значение типа «Документ» содер-жащий документ, которому принадлежит операция. Его следует использовать, если нужно передать какому либо методу или запомнить в переменную значение типа документ операции. Для доступа к данным документа непосредственно из объекта типа «Операция» следует использовать атрибут объекта «Документ».
Пример:
Опер = СоздатьОбъект("Операция");
Док = СоздатьОбъект("Документ");
Опер.ВыбратьОперации(ДатаНач, ДатаКон);
Пока Опер.ПолучитьОперацию() = 1 Цикл
Сообщить("Номер " = Опер.Документ.Номер);
Док.НайтиДокумент(Опер.ПолучитьДокумент());
КонецЦикла;
Включает/выключает проводки операции.
Синтаксис:
ВключитьПроводки(<Флаг>)
Англоязычный синоним:
EntriesOn
Пареметры:
|
<Флаг> |
Необязательный параметр. 1 — включить проводки операции. 0 — выключить проводки операции. Если параметр не передан — состояние не изменяется. |
Возвращаемое значение:
Состояние на момент вызова метода. 1 — проводки операции включены; 0 — проводки операции выключениы.
Описание:
Для каждой бухгалтерской операции может быть выполнено выключение проводок. Это значит, что проводки остаются, но исключаются из итогов. Эти действия могут выполняться пользователем интерактивно и методом ВключитьПроводки для объекта типа «Операция».
Данный метод может использоваться только для объектов, созданных функцией СоздатьОбъект. Изменяется состояние всех выбранной проводок операции одноврменно.
Пример:
Опер = СоздатьОбъект("Операция");
Опер.ВыбратьОперации(ДатаНач, ДатаКон);
Пока Опер.ПолучитьОперацию() = 1 Цикл
Опер.ВключитьПроводки(0);
КонецЦикла;
Создать новую проводку.
Синтаксис:
НоваяПроводка()
Англоязычный синоним:
NewEntry
Описание:
Метод создает новую проводку для текущей операции. Новая проводка становится текущей.
Во-первых, метод может быть вызван для объекта «Операция», созданного функцией СоздатьОбъект, при создании или изменении операции принадлежащей документу специального вида «Операция».
Во-вторых, метод может быть вызван для объекта, являющегося атрибутом документа, при создании операции принадлежащей документу, в процессе проведения документа.
Созданная проводка будет записана и повлечет изменения в бухгалтерских итогах после вызова метода операции Записать.
Пример:
* Создание и запись новой операции созданной в модуле отчета или обработки
Опер = СоздатьОбъект("Операция");
Опер.Новая();
Опер.Дата = РабочаяДата();
Опер.Содержание = "Деньги по чеку";
Опер.НоваяПроводка();
Опер.Дебет.Счет = СчетПоКоду("5 0");
Опер.Кредит.Счет = СчетПоКоду("51");
Опер.Сумма = 1000000;
Опер.Записать();
* Запись операции в модуле документа в процессе проведения
Процедура ОбработкаПроведения()
Операция.Содержание = "Выдача денег из кассы";
Операция.НоваяПроводка();
Операция.Дебет.Счет = СчетПоКоду("71");
Операция.Дебет.Сотрудники = Сотрудник;
Операция.Кредит.Счет = СчетПоКоду("50");
Операция.Сумма = СуммаВыдачи;
Операция.Записать();
КонецПроцедуры
Создает новую корреспонденцию проводки.
Синтаксис:
НоваяКорреспонденция()
Англоязычный синоним:
NewCorrespondence
Описание:
Метод НоваяКорреспонденция создает новую корреспонденцию для проводки. Метод должен использоваться после того, как новая проводка создана с использованием метода НоваяПроводка.
Данный метод предназначен для формирования сложных проводок, состоящих из нескольких корреспонденции.
Для проводки может быть создано практически неограниченное число корреспонденции путем последовательного вызова метода НоваяКорреспонденция. После создания корреспонденции изменение атрибутов проводки вызывает изменение атрибутов новой корреспонденции.
Пример:
Процедура ОбработкаПроведения()
Операция.Содержание = "Выдача денег из кассы";
Операция.НоваяПроводка();
Операция.Кредит.Счет = СчетПоКоду("50");
Операция.Сумма = Итог("СуммаВыдачи");
ВыбратьСтроки();
Пока ПолучитьСтроку() = 1 Цикл
Операция.НоваяКорреспонденция();
Операция.Дебет.Счет = СчетПоКоду("71");
Операция.Дебет.Сотрудники = Сотрудник;
Операция.Сумма = СуммаВыдачи;
КонецЦикла;
Операция.Записать();
КонецПроцедуры
Проверить проводку на соответствие корректным проводкам.
Синтаксис:
ПроверитьПроводку()
Англоязычный синоним:
CheckEntry
Возвращаемое значение:
Число: 1 — проводка соответствует корректным проводкам; 0 — не соответствует.
Описание:
Метод ПроверитьПроводку проверяет проводку на соответствие корректным проводкам.
Пример:
Опер = СоздатьОбъект("Операция");
Опер.НайтиОперацию(ВыбрДок);
Пока Опер.КоличествоПроводок() > 0 Цикл
Опер.ПолучитьПроводкуПоНомеру(1);
Если Опер.ПроверитьПроводку() = 0 Тогда
Опер.УдалитьПроводку();
КонецЕсли;
КонецЦикла;
Опер.Записать();
Удалить проводку.
Синтаксис:
УдалитьПроводку()
Англоязычный синоним:
DeleteEntry
Описание:
Метод удаляет текущую проводку или корреспонденцию операции. Метод может быть вызван объектом «Операция», созданным функцией СоздатьОбъект, при создании или изменении операции принадлежащей документу специального вида «Операция».
Собственно изменение в составе проводок будут записаны и повлекут из-менния в бухгалтерских итогах после вызова метода операции Записать.
Пример:
Опер = СоздатьОбъект("Операция");
Опер.НайтиОперацию(ВыбрДок);
Пока Опер.КоличествоПроводок() > 0 Цикл
Опер.ПолучитьПроводкуПоНомеру(1);
Опер.УдалитьПроводку();
КонецЦикла;
Опер.Записать();
